flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

{
  description = "A command-line utility and Rust library to compute the WPA pre-shared key of a Wi-Fi SSID and passphrase";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    naersk = {
      url = "github:nix-community/naersk";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{
      self,
      nixpkgs,
      flake-parts,
      naersk,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      perSystem =
        { pkgs, system, ... }:
        let
          naersk' = pkgs.callPackage naersk { };
        in
        rec {
          # nix build
          # nix run . -- --help
          packages.default = packages.wpa-psk-cli;

          # nix build .#wpa-psk-cli
          # nix run .#wpa-psk-cli -- --help
          packages.wpa-psk-cli = naersk'.buildPackage {
            pname = "wpa-psk-cli";
            src = builtins.path {
              path = ./.;
              name = "wpa-psk";
            };
            meta.mainProgram = "wpa-psk";
          };

          # nix develop
          devShells.default = pkgs.mkShell {
            nativeBuildInputs = with pkgs; [
              rustc
              cargo
              rustfmt
              clippy
              cargo-audit
              cargo-edit
              rust-analyzer
            ];
          };

          # nix fmt
          formatter = pkgs.nixfmt-tree;
        };
    };
}