blob: 2076939df9cc05be2d81f6f01455ba6b2167d08b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
{
description = "Run the PostgreSQL server off a temporary data directory";
inputs = {
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
flake-parts.url = "github:hercules-ci/flake-parts";
};
outputs =
inputs@{
self,
nixpkgs,
flake-parts,
...
}:
flake-parts.lib.mkFlake { inherit inputs; } {
systems = [
"x86_64-linux"
"aarch64-linux"
"aarch64-darwin"
];
perSystem =
{
self',
pkgs,
lib,
...
}:
let
version = builtins.head (lib.splitString "\n" (builtins.readFile ./version));
revision = lib.toString (self.shortRev or self.dirtyShortRev or "unknown");
mkPackage =
{
postgresql,
suffix ? "",
}:
pkgs.stdenv.mkDerivation {
name = "temp-postgres-${version}-${revision}${suffix}";
version = "${version}-${revision}";
src = lib.cleanSource (
builtins.path {
path = ./.;
name = "temp-postgres";
}
);
nativeBuildInputs = [ pkgs.makeBinaryWrapper ];
installPhase = ''
mkdir -p $out/bin
cp temp-postgres.sh $out/bin/temp-postgres
mkdir -p $out/man/man1
cp temp-postgres.1 $out/man/man1/temp-postgres.1
wrapProgram $out/bin/temp-postgres --prefix PATH : ${lib.makeBinPath [ postgresql ]}
'';
};
postgresqlVersions = lib.mapAttrs' (
name: drv:
let
postgresqlVersion = lib.removePrefix "postgresql_" name;
in
lib.nameValuePair "temp-postgres_${postgresqlVersion}" (mkPackage {
postgresql = drv;
suffix = "_${postgresqlVersion}";
})
) pkgs.postgresqlVersions;
in
{
packages = {
default = self'.packages.temp-postgres;
temp-postgres = mkPackage { postgresql = pkgs.postgresql; };
}
// postgresqlVersions;
formatter = pkgs.nixfmt-tree;
devShells.default = pkgs.mkShell {
nativeBuildInputs = with pkgs; [
gnumake
gzip
mandoc
postgresql
shellcheck
];
shellHook = ''
export FLAKE=${self}
'';
};
};
};
}
|